Import from gcc repository:
2003-07-07 Zack Weinberg <zack@codesourcery.com> * gettext.m4: Delete all former contents. (ZW_GNU_GETTEXT_SISTER_DIR): New macro. * progtest.m4: New file. 2003-07-04 Zack Weinberg <zack@codesourcery.com> * gettext.m4: New file - copy of gettext.m4 from binutils
This commit is contained in:
Zack Weinberg
parent
76bff7057c
commit
86d22d06c9
|
|
@ -1,3 +1,14 @@
|
|||
2003-07-07 Zack Weinberg <zack@codesourcery.com>
|
||||
|
||||
* gettext.m4: Delete all former contents.
|
||||
(ZW_GNU_GETTEXT_SISTER_DIR): New macro.
|
||||
* progtest.m4: New file.
|
||||
|
||||
2003-07-04 Zack Weinberg <zack@codesourcery.com>
|
||||
|
||||
* gettext.m4: New file - copy of gettext.m4 from binutils
|
||||
CVS, with added AC_ISC_POSIX macro from gcc/aclocal.m4.
|
||||
|
||||
2003-05-14 Kelley Cook <kelleycook@wideopenwest.com>
|
||||
|
||||
* acinclude.m4: Accept i[3456789]86 for machine type.
|
||||
|
|
|
|||
|
|
@ -0,0 +1,66 @@
|
|||
# intl sister-directory configuration rules.
|
||||
#
|
||||
|
||||
# The idea behind this macro is that there's no need to repeat all the
|
||||
# autoconf probes done by the intl directory - it's already done them
|
||||
# for us. In fact, there's no need even to look at the cache for the
|
||||
# answers. All we need to do is nab a few pieces of information.
|
||||
# The intl directory is set up to make this easy, by generating a
|
||||
# small file which can be sourced as a shell script; then we produce
|
||||
# the necessary substitutions and definitions for this directory.
|
||||
|
||||
AC_DEFUN(ZW_GNU_GETTEXT_SISTER_DIR,
|
||||
[# If we haven't got the data from the intl directory,
|
||||
# assume NLS is disabled.
|
||||
USE_NLS=no AC_SUBST(USE_NLS)
|
||||
LIBINTL= AC_SUBST(LIBINTL)
|
||||
LIBINTL_DEP= AC_SUBST(LIBINTL_DEP)
|
||||
INCINTL= AC_SUBST(INCINTL)
|
||||
XGETTEXT= AC_SUBST(XGETTEXT)
|
||||
GMSGFMT= AC_SUBST(GMSGFMT)
|
||||
POSUB= AC_SUBST(POSUB)
|
||||
if test -f ../intl/config.intl; then
|
||||
. ../intl/config.intl
|
||||
fi
|
||||
AC_MSG_CHECKING([whether NLS is requested])
|
||||
if test x"$USE_NLS" != xyes; then
|
||||
AC_MSG_RESULT(no)
|
||||
else
|
||||
AC_MSG_RESULT(yes)
|
||||
AC_DEFINE(ENABLE_NLS, 1,
|
||||
[Define to 1 if translation of program messages to the
|
||||
user's native language is requested.])
|
||||
|
||||
AC_MSG_CHECKING(for catalogs to be installed)
|
||||
# Look for .po and .gmo files in the source directory.
|
||||
CATALOGS= AC_SUBST(CATALOGS)
|
||||
XLINGUAS=
|
||||
for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
|
||||
# If there aren't any .gmo files the shell will give us the
|
||||
# literal string "../path/to/srcdir/po/*.gmo" which has to be
|
||||
# weeded out.
|
||||
case "$cat" in *\**)
|
||||
continue;;
|
||||
esac
|
||||
# The quadruple backslash is collapsed to a double backslash
|
||||
# by the backticks, then collapsed again by the double quotes,
|
||||
# leaving us with one backslash in the sed expression (right
|
||||
# before the dot that mustn't act as a wildcard).
|
||||
cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
|
||||
lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
|
||||
# The user is allowed to set LINGUAS to a list of languages to
|
||||
# install catalogs for. If it's empty that means "all of them."
|
||||
if test "x$LINGUAS" = x; then
|
||||
CATALOGS="$CATALOGS $cat"
|
||||
XLINGUAS="$XLINGUAS $lang"
|
||||
else
|
||||
case "$LINGUAS" in *$lang*)
|
||||
CATALOGS="$CATALOGS $cat"
|
||||
XLINGUAS="$XLINGUAS $lang"
|
||||
;;
|
||||
esac
|
||||
fi
|
||||
done
|
||||
LINGUAS="$XLINGUAS"
|
||||
AC_MSG_RESULT($LINGUAS)
|
||||
fi])
|
||||
|
|
@ -0,0 +1,91 @@
|
|||
# progtest.m4 serial 3 (gettext-0.12)
|
||||
dnl Copyright (C) 1996-2003 Free Software Foundation, Inc.
|
||||
dnl This file is free software, distributed under the terms of the GNU
|
||||
dnl General Public License. As a special exception to the GNU General
|
||||
dnl Public License, this file may be distributed as part of a program
|
||||
dnl that contains a configuration script generated by Autoconf, under
|
||||
dnl the same distribution terms as the rest of that program.
|
||||
dnl
|
||||
dnl This file can can be used in projects which are not available under
|
||||
dnl the GNU General Public License or the GNU Library General Public
|
||||
dnl License but which still want to provide support for the GNU gettext
|
||||
dnl functionality.
|
||||
dnl Please note that the actual code of the GNU gettext library is covered
|
||||
dnl by the GNU Library General Public License, and the rest of the GNU
|
||||
dnl gettext package package is covered by the GNU General Public License.
|
||||
dnl They are *not* in the public domain.
|
||||
|
||||
dnl Authors:
|
||||
dnl Ulrich Drepper <drepper@cygnus.com>, 1996.
|
||||
|
||||
# Search path for a program which passes the given test.
|
||||
|
||||
dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
|
||||
dnl TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
|
||||
AC_DEFUN([AM_PATH_PROG_WITH_TEST],
|
||||
[
|
||||
# Prepare PATH_SEPARATOR.
|
||||
# The user is always right.
|
||||
if test "${PATH_SEPARATOR+set}" != set; then
|
||||
echo "#! /bin/sh" >conf$$.sh
|
||||
echo "exit 0" >>conf$$.sh
|
||||
chmod +x conf$$.sh
|
||||
if (PATH="/nonexistent;."; conf$$.sh) >/dev/null 2>&1; then
|
||||
PATH_SEPARATOR=';'
|
||||
else
|
||||
PATH_SEPARATOR=:
|
||||
fi
|
||||
rm -f conf$$.sh
|
||||
fi
|
||||
|
||||
# Find out how to test for executable files. Don't use a zero-byte file,
|
||||
# as systems may use methods other than mode bits to determine executability.
|
||||
cat >conf$$.file <<_ASEOF
|
||||
#! /bin/sh
|
||||
exit 0
|
||||
_ASEOF
|
||||
chmod +x conf$$.file
|
||||
if test -x conf$$.file >/dev/null 2>&1; then
|
||||
ac_executable_p="test -x"
|
||||
else
|
||||
ac_executable_p="test -f"
|
||||
fi
|
||||
rm -f conf$$.file
|
||||
|
||||
# Extract the first word of "$2", so it can be a program name with args.
|
||||
set dummy $2; ac_word=[$]2
|
||||
AC_MSG_CHECKING([for $ac_word])
|
||||
AC_CACHE_VAL(ac_cv_path_$1,
|
||||
[case "[$]$1" in
|
||||
[[\\/]]* | ?:[[\\/]]*)
|
||||
ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
|
||||
;;
|
||||
*)
|
||||
ac_save_IFS="$IFS"; IFS=$PATH_SEPARATOR
|
||||
for ac_dir in ifelse([$5], , $PATH, [$5]); do
|
||||
IFS="$ac_save_IFS"
|
||||
test -z "$ac_dir" && ac_dir=.
|
||||
for ac_exec_ext in '' $ac_executable_extensions; do
|
||||
if $ac_executable_p "$ac_dir/$ac_word$ac_exec_ext"; then
|
||||
if [$3]; then
|
||||
ac_cv_path_$1="$ac_dir/$ac_word$ac_exec_ext"
|
||||
break 2
|
||||
fi
|
||||
fi
|
||||
done
|
||||
done
|
||||
IFS="$ac_save_IFS"
|
||||
dnl If no 4th arg is given, leave the cache variable unset,
|
||||
dnl so AC_PATH_PROGS will keep looking.
|
||||
ifelse([$4], , , [ test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
|
||||
])dnl
|
||||
;;
|
||||
esac])dnl
|
||||
$1="$ac_cv_path_$1"
|
||||
if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
|
||||
AC_MSG_RESULT([$]$1)
|
||||
else
|
||||
AC_MSG_RESULT(no)
|
||||
fi
|
||||
AC_SUBST($1)dnl
|
||||
])
|
||||
Loading…
Reference in New Issue