6757cf5769
We add a new AC_SUBST to warning.m4 so that the test if the warning is supported is centralized, but the warning can be enabled per directory. binutils/ChangeLog: 2016-03-31 Trevor Saunders <tbsaunde+binutils@tbsaunde.org> * configure: Regenerate. gprof/ChangeLog: 2016-03-31 Trevor Saunders <tbsaunde+binutils@tbsaunde.org> * configure: Regenerate. ld/ChangeLog: 2016-03-31 Trevor Saunders <tbsaunde+binutils@tbsaunde.org> * configure: Regenerate. opcodes/ChangeLog: 2016-03-31 Trevor Saunders <tbsaunde+binutils@tbsaunde.org> * configure: Regenerate. bfd/ChangeLog: 2016-03-31 Trevor Saunders <tbsaunde+binutils@tbsaunde.org> * configure: Regenerate. * warning.m4: Add WARN_WRITE_STRINGS AC_SUBST. gold/ChangeLog: 2016-03-31 Trevor Saunders <tbsaunde+binutils@tbsaunde.org> * configure: Regenerate. gas/ChangeLog: 2016-03-31 Trevor Saunders <tbsaunde+binutils@tbsaunde.org> * Makefile.am: Add WARN_WRITE_STRINGS to WARN_CFLAGS. * Makefile.in: Regenerate. * configure: Likewise.
92 lines
3.0 KiB
Plaintext
92 lines
3.0 KiB
Plaintext
dnl Common configure.ac fragment
|
|
dnl
|
|
dnl Copyright (C) 2012-2016 Free Software Foundation, Inc.
|
|
dnl
|
|
dnl This file is free software; you can redistribute it and/or modify
|
|
dnl it under the terms of the GNU General Public License as published by
|
|
dnl the Free Software Foundation; either version 3 of the License, or
|
|
dnl (at your option) any later version.
|
|
dnl
|
|
dnl This program is distributed in the hope that it will be useful,
|
|
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
dnl GNU General Public License for more details.
|
|
dnl
|
|
dnl You should have received a copy of the GNU General Public License
|
|
dnl along with this program; see the file COPYING3. If not see
|
|
dnl <http://www.gnu.org/licenses/>.
|
|
dnl
|
|
|
|
AC_DEFUN([AM_BINUTILS_WARNINGS],[
|
|
# Set the 'development' global.
|
|
. $srcdir/../bfd/development.sh
|
|
|
|
# Default set of GCC warnings to enable.
|
|
GCC_WARN_CFLAGS="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
|
|
|
|
# Add -Wshadow if the compiler is a sufficiently recent version of GCC.
|
|
AC_EGREP_CPP([^[0-3]$],[__GNUC__],,GCC_WARN_CFLAGS="$GCC_WARN_CFLAGS -Wshadow")
|
|
|
|
# Add -Wstack-usage if the compiler is a sufficiently recent version of GCC.
|
|
AC_EGREP_CPP([^[0-4]$],[__GNUC__],,GCC_WARN_CFLAGS="$GCC_WARN_CFLAGS -Wstack-usage=262144")
|
|
|
|
# Set WARN_WRITE_STRINGS if the compiler supports -Wwrite-strings.
|
|
WARN_WRITE_STRINGS=""
|
|
AC_EGREP_CPP([^[0-3]$],[__GNUC__],,WARN_WRITE_STRINGS="-Wwrite-strings")
|
|
|
|
AC_ARG_ENABLE(werror,
|
|
[ --enable-werror treat compile warnings as errors],
|
|
[case "${enableval}" in
|
|
yes | y) ERROR_ON_WARNING="yes" ;;
|
|
no | n) ERROR_ON_WARNING="no" ;;
|
|
*) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
|
|
esac])
|
|
|
|
# Disable -Wformat by default when using gcc on mingw
|
|
case "${host}" in
|
|
*-*-mingw32*)
|
|
if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
|
|
GCC_WARN_CFLAGS="$GCC_WARN_CFLAGS -Wno-format"
|
|
fi
|
|
;;
|
|
*) ;;
|
|
esac
|
|
|
|
# Enable -Werror by default when using gcc. Turn it off for releases.
|
|
if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" -a "$development" = true ; then
|
|
ERROR_ON_WARNING=yes
|
|
fi
|
|
|
|
NO_WERROR=
|
|
if test "${ERROR_ON_WARNING}" = yes ; then
|
|
GCC_WARN_CFLAGS="$GCC_WARN_CFLAGS -Werror"
|
|
NO_WERROR="-Wno-error"
|
|
fi
|
|
|
|
if test "${GCC}" = yes ; then
|
|
WARN_CFLAGS="${GCC_WARN_CFLAGS}"
|
|
fi
|
|
|
|
AC_ARG_ENABLE(build-warnings,
|
|
[ --enable-build-warnings enable build-time compiler warnings],
|
|
[case "${enableval}" in
|
|
yes) WARN_CFLAGS="${GCC_WARN_CFLAGS}";;
|
|
no) if test "${GCC}" = yes ; then
|
|
WARN_CFLAGS="-w"
|
|
fi;;
|
|
,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
|
|
WARN_CFLAGS="${GCC_WARN_CFLAGS} ${t}";;
|
|
*,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
|
|
WARN_CFLAGS="${t} ${GCC_WARN_CFLAGS}";;
|
|
*) WARN_CFLAGS=`echo "${enableval}" | sed -e "s/,/ /g"`;;
|
|
esac])
|
|
|
|
if test x"$silent" != x"yes" && test x"$WARN_CFLAGS" != x""; then
|
|
echo "Setting warning flags = $WARN_CFLAGS" 6>&1
|
|
fi
|
|
|
|
AC_SUBST(WARN_CFLAGS)
|
|
AC_SUBST(NO_WERROR)
|
|
AC_SUBST(WARN_WRITE_STRINGS)
|
|
])
|