908a31e1b1
* configure.in (arm-*-netbsdelf*): Add configuration. (configure): Regenerated. From-SVN: r65691
220 lines
6.7 KiB
Plaintext
220 lines
6.7 KiB
Plaintext
dnl Process this with autoconf to create configure
|
|
AC_INIT(fficonfig.h.in)
|
|
AM_CONFIG_HEADER(fficonfig.h)
|
|
|
|
# This works around the fact that libtool configuration may change LD
|
|
# for this particular configuration, but some shells, instead of
|
|
# keeping the changes in LD private, export them just because LD is
|
|
# exported.
|
|
ORIGINAL_LD_FOR_MULTILIBS=$LD
|
|
|
|
dnl Default to --enable-multilib
|
|
AC_ARG_ENABLE(multilib,
|
|
[ --enable-multilib build many library versions (default)],
|
|
[case "${enableval}" in
|
|
yes) multilib=yes ;;
|
|
no) multilib=no ;;
|
|
*) AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
|
|
esac], [multilib=yes])dnl
|
|
|
|
dnl We may get other options which we don't document:
|
|
dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
|
|
|
|
if test "${srcdir}" = "."; then
|
|
if test "${with_target_subdir}" != "."; then
|
|
libffi_basedir="${with_multisrctop}../"
|
|
else
|
|
libffi_basedir="${with_multisrctop}"
|
|
fi
|
|
else
|
|
libffi_basedir=
|
|
fi
|
|
AC_SUBST(libffi_basedir)
|
|
AC_CONFIG_AUX_DIR(${libffi_basedir}..)
|
|
|
|
AC_CANONICAL_HOST
|
|
|
|
AM_PROG_LIBTOOL
|
|
|
|
AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
|
|
|
|
AC_EXEEXT
|
|
AM_MAINTAINER_MODE
|
|
|
|
AC_PROG_CC
|
|
AC_PROG_LIBTOOL
|
|
|
|
TARGETDIR="unknown"
|
|
case "$host" in
|
|
mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
|
|
i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
|
|
i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
|
|
i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
|
|
i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
|
|
i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
|
|
i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
|
|
i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
|
|
i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
|
|
sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
|
|
sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
|
|
sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
|
|
sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
|
|
alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
|
|
ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
|
|
m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
|
|
mips64*-*);;
|
|
mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
|
|
powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
|
|
powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
|
|
powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
|
|
powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
|
|
rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
|
|
arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
|
|
arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
|
|
s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
|
|
s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
|
|
x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
|
|
sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
|
|
esac
|
|
|
|
if test $TARGETDIR = unknown; then
|
|
AC_ERROR("libffi has not been ported to $host.")
|
|
fi
|
|
|
|
AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
|
|
AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
|
|
AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
|
|
AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
|
|
AM_CONDITIONAL(X86, test x$TARGET = xX86)
|
|
AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
|
|
AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
|
|
AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
|
|
AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
|
|
AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
|
|
AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
|
|
AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
|
|
AM_CONDITIONAL(ARM, test x$TARGET = xARM)
|
|
AM_CONDITIONAL(S390, test x$TARGET = xS390)
|
|
AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
|
|
AM_CONDITIONAL(SH, test x$TARGET = xSH)
|
|
|
|
if test x$TARGET = xMIPS_LINUX; then
|
|
TARGET=MIPS
|
|
fi
|
|
|
|
AC_HEADER_STDC
|
|
AC_CHECK_FUNCS(memcpy)
|
|
AC_FUNC_ALLOCA
|
|
|
|
dnl AC_CHECK_SIZEOF(char)
|
|
AC_COMPILE_CHECK_SIZEOF(short)
|
|
AC_COMPILE_CHECK_SIZEOF(int)
|
|
AC_COMPILE_CHECK_SIZEOF(long)
|
|
AC_COMPILE_CHECK_SIZEOF(long long)
|
|
AC_COMPILE_CHECK_SIZEOF(float)
|
|
AC_COMPILE_CHECK_SIZEOF(double)
|
|
AC_COMPILE_CHECK_SIZEOF(long double)
|
|
|
|
AC_COMPILE_CHECK_SIZEOF(void *)
|
|
AC_C_BIGENDIAN_CROSS
|
|
|
|
if test x$TARGET = xSPARC; then
|
|
AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
|
|
libffi_cv_as_sparc_ua_pcrel, [
|
|
save_CFLAGS="$CFLAGS"
|
|
save_LDFLAGS="$LDFLAGS"
|
|
CFLAGS="$CFLAGS -fpic"
|
|
LDFLAGS="$LDFLAGS -shared"
|
|
AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
|
|
[libffi_cv_as_sparc_ua_pcrel=yes],
|
|
[libffi_cv_as_sparc_ua_pcrel=no])
|
|
CFLAGS="$save_CFLAGS"
|
|
LDFLAGS="$save_LDFLAGS"])
|
|
if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
|
|
AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
|
|
[Define if your assembler and linker support unaligned PC relative relocs.])
|
|
fi
|
|
fi
|
|
|
|
AC_SUBST(TARGET)
|
|
AC_SUBST(TARGETDIR)
|
|
|
|
AC_SUBST(SHELL)
|
|
|
|
AC_ARG_ENABLE(debug,
|
|
[ --enable-debug debugging mode],
|
|
if test "$enable_debug" = "yes"; then
|
|
AC_DEFINE(FFI_DEBUG)
|
|
fi)
|
|
|
|
AC_ARG_ENABLE(structs,
|
|
[ --disable-structs omit code for struct support],
|
|
if test "$enable_structs" = "no"; then
|
|
AC_DEFINE(FFI_NO_STRUCTS)
|
|
fi)
|
|
|
|
AC_ARG_ENABLE(raw-api,
|
|
[ --disable-raw-api make the raw api unavailable],
|
|
if test "$enable_raw_api" = "no"; then
|
|
AC_DEFINE(FFI_NO_RAW_API)
|
|
fi)
|
|
|
|
AC_ARG_ENABLE(purify-safety,
|
|
[ --enable-purify-safety purify-safe mode],
|
|
if test "$enable_purify_safety" = "yes"; then
|
|
AC_DEFINE(USING_PURIFY)
|
|
fi)
|
|
|
|
if test -n "$with_cross_host" &&
|
|
test x"$with_cross_host" != x"no"; then
|
|
toolexecdir='$(exec_prefix)/$(target_alias)'
|
|
toolexeclibdir='$(toolexecdir)/lib'
|
|
else
|
|
toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
|
|
toolexeclibdir='$(libdir)'
|
|
fi
|
|
multi_os_directory=`$CC -print-multi-os-directory`
|
|
case $multi_os_directory in
|
|
.) ;; # Avoid trailing /.
|
|
*) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
|
|
esac
|
|
AC_SUBST(toolexecdir)
|
|
AC_SUBST(toolexeclibdir)
|
|
|
|
if test "${multilib}" = "yes"; then
|
|
multilib_arg="--enable-multilib"
|
|
else
|
|
multilib_arg=
|
|
fi
|
|
|
|
AC_OUTPUT(include/Makefile include/ffi.h Makefile,
|
|
[
|
|
if test -n "$CONFIG_FILES"; then
|
|
LD="${ORIGINAL_LD_FOR_MULTILIBS}"
|
|
ac_file=Makefile . ${srcdir}/${libffi_basedir}../config-ml.in
|
|
fi
|
|
],
|
|
srcdir=${srcdir}
|
|
host=${host}
|
|
target=${target}
|
|
with_multisubdir=${with_multisubdir}
|
|
ac_configure_args="${multilib_arg} ${ac_configure_args}"
|
|
CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
|
|
libffi_basedir=${libffi_basedir}
|
|
CC="${CC}"
|
|
DEFS="$DEFS"
|
|
ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
|
|
test ! -d include && mkdir include
|
|
test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
|
|
if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then
|
|
echo fficonfig.h unchanged
|
|
else
|
|
echo Moving fficonfig.h to include/fficonfig.h
|
|
cp fficonfig.h include/fficonfig.h
|
|
fi
|
|
)
|
|
|
|
# Make target subdirectories if required.
|
|
test -d src || mkdir src
|
|
test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}
|