554 lines
20 KiB
Plaintext
554 lines
20 KiB
Plaintext
# shlibpath.m4 - Define LTDL_SHLIBPATH_VAR. -*-Autoconf-*-
|
|
## Copyright 1996, 1997, 1998, 1999, 2000, 2001, 2005
|
|
## Free Software Foundation, Inc.
|
|
## Originally by Gordon Matzigkeit <gord@gnu.ai.mit.edu>, 1996
|
|
##
|
|
## This program is free software; you can redistribute it and/or modify
|
|
## it under the terms of the GNU General Public License as published by
|
|
## the Free Software Foundation; either version 2 of the License, or
|
|
## (at your option) any later version.
|
|
##
|
|
## This program is distributed in the hope that it will be useful, but
|
|
## WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
## General Public License for more details.
|
|
##
|
|
## You should have received a copy of the GNU General Public License
|
|
## along with this program; if not, write to the Free Software
|
|
## Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
|
|
##
|
|
## As a special exception to the GNU General Public License, if you
|
|
## distribute this file as part of a program that contains a
|
|
## configuration script generated by Autoconf, you may include it under
|
|
## the same distribution terms that you use for the rest of that program.
|
|
|
|
# AC_LIBTOOL_SYS_DYNAMIC_LINKER
|
|
# -----------------------------
|
|
# PORTME Fill in your ld.so characteristics
|
|
AC_DEFUN([AC_LIBTOOL_SYS_DYNAMIC_LINKER],
|
|
[AC_MSG_CHECKING([dynamic linker characteristics])
|
|
library_names_spec=
|
|
libname_spec='lib$name'
|
|
soname_spec=
|
|
shrext=".so"
|
|
postinstall_cmds=
|
|
postuninstall_cmds=
|
|
finish_cmds=
|
|
finish_eval=
|
|
shlibpath_var=
|
|
shlibpath_overrides_runpath=unknown
|
|
version_type=none
|
|
dynamic_linker="$host_os ld.so"
|
|
sys_lib_dlsearch_path_spec="/lib /usr/lib"
|
|
if test "$GCC" = yes; then
|
|
sys_lib_search_path_spec=`$CC -print-search-dirs | grep "^libraries:" | sed -e "s/^libraries://" -e "s,=/,/,g"`
|
|
if echo "$sys_lib_search_path_spec" | grep ';' >/dev/null ; then
|
|
# if the path contains ";" then we assume it to be the separator
|
|
# otherwise default to the standard path separator (i.e. ":") - it is
|
|
# assumed that no part of a normal pathname contains ";" but that should
|
|
# okay in the real world where ";" in dirpaths is itself problematic.
|
|
sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | sed -e 's/;/ /g'`
|
|
else
|
|
sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | sed -e "s/$PATH_SEPARATOR/ /g"`
|
|
fi
|
|
else
|
|
sys_lib_search_path_spec="/lib /usr/lib /usr/local/lib"
|
|
fi
|
|
need_lib_prefix=unknown
|
|
hardcode_into_libs=no
|
|
|
|
# when you set need_version to no, make sure it does not cause -set_version
|
|
# flags to be left without arguments
|
|
need_version=unknown
|
|
|
|
case $host_os in
|
|
aix3*)
|
|
version_type=linux
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix $libname.a'
|
|
shlibpath_var=LIBPATH
|
|
|
|
# AIX 3 has no versioning support, so we append a major version to the name.
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
;;
|
|
|
|
aix4* | aix5*)
|
|
version_type=linux
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
hardcode_into_libs=yes
|
|
if test "$host_cpu" = ia64; then
|
|
# AIX 5 supports IA64
|
|
library_names_spec='${libname}${release}${shared_ext}$major ${libname}${release}${shared_ext}$versuffix $libname${shared_ext}'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
else
|
|
# With GCC up to 2.95.x, collect2 would create an import file
|
|
# for dependence libraries. The import file would start with
|
|
# the line `#! .'. This would cause the generated library to
|
|
# depend on `.', always an invalid library. This was fixed in
|
|
# development snapshots of GCC prior to 3.0.
|
|
case $host_os in
|
|
aix4 | aix4.[[01]] | aix4.[[01]].*)
|
|
if { echo '#if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 97)'
|
|
echo ' yes '
|
|
echo '#endif'; } | ${CC} -E - | grep yes > /dev/null; then
|
|
:
|
|
else
|
|
can_build_shared=no
|
|
fi
|
|
;;
|
|
esac
|
|
# AIX (on Power*) has no versioning support, so currently we can not hardcode correct
|
|
# soname into executable. Probably we can add versioning support to
|
|
# collect2, so additional links can be useful in future.
|
|
if test "$aix_use_runtimelinking" = yes; then
|
|
# If using run time linking (on AIX 4.2 or later) use lib<name>.so
|
|
# instead of lib<name>.a to let people know that these are not
|
|
# typical AIX shared libraries.
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
else
|
|
# We preserve .a as extension for shared libraries through AIX4.2
|
|
# and later when we are not doing run time linking.
|
|
library_names_spec='${libname}${release}.a $libname.a'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
fi
|
|
shlibpath_var=LIBPATH
|
|
fi
|
|
;;
|
|
|
|
amigaos*)
|
|
library_names_spec='$libname.ixlibrary $libname.a'
|
|
# Create ${libname}_ixlibrary.a entries in /sys/libs.
|
|
finish_eval='for lib in `ls $libdir/*.ixlibrary 2>/dev/null`; do libname=`$echo "X$lib" | $Xsed -e '\''s%^.*/\([[^/]]*\)\.ixlibrary$%\1%'\''`; test $rm /sys/libs/${libname}_ixlibrary.a; $show "(cd /sys/libs && $LN_S $lib ${libname}_ixlibrary.a)"; (cd /sys/libs && $LN_S $lib ${libname}_ixlibrary.a) || exit 1; done'
|
|
;;
|
|
|
|
beos*)
|
|
library_names_spec='${libname}${shared_ext}'
|
|
dynamic_linker="$host_os ld.so"
|
|
shlibpath_var=LIBRARY_PATH
|
|
;;
|
|
|
|
bsdi4*)
|
|
version_type=linux
|
|
need_version=no
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
finish_cmds='PATH="\$PATH:/sbin" ldconfig $libdir'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
sys_lib_search_path_spec="/shlib /usr/lib /usr/X11/lib /usr/contrib/lib /lib /usr/local/lib"
|
|
sys_lib_dlsearch_path_spec="/shlib /usr/lib /usr/local/lib"
|
|
# the default ld.so.conf also contains /usr/contrib/lib and
|
|
# /usr/X11R6/lib (/usr/X11 is a link to /usr/X11R6), but let us allow
|
|
# libtool to hard-code these into programs
|
|
;;
|
|
|
|
cygwin* | mingw* | pw32*)
|
|
version_type=windows
|
|
shrext=".dll"
|
|
need_version=no
|
|
need_lib_prefix=no
|
|
|
|
case $GCC,$host_os in
|
|
yes,cygwin* | yes,mingw* | yes,pw32*)
|
|
library_names_spec='$libname.dll.a'
|
|
# DLL is installed to $(libdir)/../bin by postinstall_cmds
|
|
postinstall_cmds='base_file=`basename \${file}`~
|
|
dlpath=`$SHELL 2>&1 -c '\''. $dir/'\''\${base_file}'\''i;echo \$dlname'\''`~
|
|
dldir=$destdir/`dirname \$dlpath`~
|
|
test -d \$dldir || mkdir -p \$dldir~
|
|
$install_prog $dir/$dlname \$dldir/$dlname'
|
|
postuninstall_cmds='dldll=`$SHELL 2>&1 -c '\''. $file; echo \$dlname'\''`~
|
|
dlpath=$dir/\$dldll~
|
|
$rm \$dlpath'
|
|
shlibpath_overrides_runpath=yes
|
|
|
|
case $host_os in
|
|
cygwin*)
|
|
# Cygwin DLLs use 'cyg' prefix rather than 'lib'
|
|
soname_spec='`echo ${libname} | sed -e 's/^lib/cyg/'``echo ${release} | sed -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
|
|
sys_lib_search_path_spec="/lib /lib/w32api /usr/lib /usr/local/lib"
|
|
;;
|
|
mingw*)
|
|
# MinGW DLLs use traditional 'lib' prefix
|
|
soname_spec='${libname}`echo ${release} | sed -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
|
|
sys_lib_search_path_spec=`$CC -print-search-dirs | grep "^libraries:" | sed -e "s/^libraries://" -e "s,=/,/,g"`
|
|
if echo "$sys_lib_search_path_spec" | [grep ';[c-zC-Z]:/' >/dev/null]; then
|
|
# It is most probably a Windows format PATH printed by
|
|
# mingw gcc, but we are running on Cygwin. Gcc prints its search
|
|
# path with ; separators, and with drive letters. We can handle the
|
|
# drive letters (cygwin fileutils understands them), so leave them,
|
|
# especially as we might pass files found there to a mingw objdump,
|
|
# which wouldn't understand a cygwinified path. Ahh.
|
|
sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | sed -e 's/;/ /g'`
|
|
else
|
|
sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | sed -e "s/$PATH_SEPARATOR/ /g"`
|
|
fi
|
|
;;
|
|
pw32*)
|
|
# pw32 DLLs use 'pw' prefix rather than 'lib'
|
|
library_names_spec='`echo ${libname} | sed -e 's/^lib/pw/'``echo ${release} | sed -e 's/[.]/-/g'`${versuffix}${shared_ext}'
|
|
;;
|
|
esac
|
|
;;
|
|
|
|
*)
|
|
library_names_spec='${libname}`echo ${release} | sed -e 's/[[.]]/-/g'`${versuffix}${shared_ext} $libname.lib'
|
|
;;
|
|
esac
|
|
dynamic_linker='Win32 ld.exe'
|
|
# FIXME: first we should search . and the directory the executable is in
|
|
shlibpath_var=PATH
|
|
;;
|
|
|
|
darwin* | rhapsody*)
|
|
dynamic_linker="$host_os dyld"
|
|
version_type=darwin
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
# FIXME: Relying on posixy $() will cause problems for
|
|
# cross-compilation, but unfortunately the echo tests do not
|
|
# yet detect zsh echo's removal of \ escapes.
|
|
library_names_spec='${libname}${release}${versuffix}$shared_ext ${libname}${release}${major}$shared_ext ${libname}$shared_ext'
|
|
soname_spec='${libname}${release}${major}$shared_ext'
|
|
shlibpath_overrides_runpath=yes
|
|
shlibpath_var=DYLD_LIBRARY_PATH
|
|
shrext='$(test .$module = .yes && echo .so || echo .dylib)'
|
|
# Apple's gcc prints 'gcc -print-search-dirs' doesn't operate the same.
|
|
if $CC -v 2>&1 | grep 'Apple' >/dev/null ; then
|
|
sys_lib_search_path_spec=`$CC -print-search-dirs | tr "\n" "$PATH_SEPARATOR" | sed -e 's/libraries:/@libraries:/' | tr "@" "\n" | grep "^libraries:" | sed -e "s/^libraries://" -e "s,=/,/,g" -e "s,$PATH_SEPARATOR, ,g" -e "s,.*,& /lib /usr/lib /usr/local/lib,g"`
|
|
fi
|
|
sys_lib_dlsearch_path_spec='/usr/local/lib /lib /usr/lib'
|
|
;;
|
|
|
|
dgux*)
|
|
version_type=linux
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname$shared_ext'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
;;
|
|
|
|
freebsd1*)
|
|
dynamic_linker=no
|
|
;;
|
|
|
|
freebsd*)
|
|
objformat=`test -x /usr/bin/objformat && /usr/bin/objformat || echo aout`
|
|
version_type=freebsd-$objformat
|
|
case $version_type in
|
|
freebsd-elf*)
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext} $libname${shared_ext}'
|
|
need_version=no
|
|
need_lib_prefix=no
|
|
;;
|
|
freebsd-*)
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix $libname${shared_ext}$versuffix'
|
|
need_version=yes
|
|
;;
|
|
esac
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
case $host_os in
|
|
freebsd2*)
|
|
shlibpath_overrides_runpath=yes
|
|
;;
|
|
freebsd3.[01]* | freebsdelf3.[01]*)
|
|
shlibpath_overrides_runpath=yes
|
|
hardcode_into_libs=yes
|
|
;;
|
|
*) # from 3.2 on
|
|
shlibpath_overrides_runpath=no
|
|
hardcode_into_libs=yes
|
|
;;
|
|
esac
|
|
;;
|
|
|
|
gnu*)
|
|
version_type=linux
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}${major} ${libname}${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
hardcode_into_libs=yes
|
|
;;
|
|
|
|
hpux9* | hpux10* | hpux11*)
|
|
# Give a soname corresponding to the major version so that dld.sl refuses to
|
|
# link against other versions.
|
|
version_type=sunos
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
case "$host_cpu" in
|
|
ia64*)
|
|
shrext='.so'
|
|
hardcode_into_libs=yes
|
|
dynamic_linker="$host_os dld.so"
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
shlibpath_overrides_runpath=yes # Unless +noenvvar is specified.
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
if test "X$HPUX_IA64_MODE" = X32; then
|
|
sys_lib_search_path_spec="/usr/lib/hpux32 /usr/local/lib/hpux32 /usr/local/lib"
|
|
else
|
|
sys_lib_search_path_spec="/usr/lib/hpux64 /usr/local/lib/hpux64"
|
|
fi
|
|
sys_lib_dlsearch_path_spec=$sys_lib_search_path_spec
|
|
;;
|
|
hppa*64*)
|
|
shrext='.sl'
|
|
hardcode_into_libs=yes
|
|
dynamic_linker="$host_os dld.sl"
|
|
shlibpath_var=LD_LIBRARY_PATH # How should we handle SHLIB_PATH
|
|
shlibpath_overrides_runpath=yes # Unless +noenvvar is specified.
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
sys_lib_search_path_spec="/usr/lib/pa20_64 /usr/ccs/lib/pa20_64"
|
|
sys_lib_dlsearch_path_spec=$sys_lib_search_path_spec
|
|
;;
|
|
*)
|
|
shrext='.sl'
|
|
dynamic_linker="$host_os dld.sl"
|
|
shlibpath_var=SHLIB_PATH
|
|
shlibpath_overrides_runpath=no # +s is required to enable SHLIB_PATH
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
;;
|
|
esac
|
|
# HP-UX runs *really* slowly unless shared libraries are mode 555.
|
|
postinstall_cmds='chmod 555 $lib'
|
|
;;
|
|
|
|
irix5* | irix6* | nonstopux*)
|
|
case $host_os in
|
|
nonstopux*) version_type=nonstopux ;;
|
|
*)
|
|
if test "$lt_cv_prog_gnu_ld" = yes; then
|
|
version_type=linux
|
|
else
|
|
version_type=irix
|
|
fi ;;
|
|
esac
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${release}${shared_ext} $libname${shared_ext}'
|
|
case $host_os in
|
|
irix5* | nonstopux*)
|
|
libsuff= shlibsuff=
|
|
;;
|
|
*)
|
|
case $LD in # libtool.m4 will add one of these switches to LD
|
|
*-32|*"-32 "|*-melf32bsmip|*"-melf32bsmip ")
|
|
libsuff= shlibsuff= libmagic=32-bit;;
|
|
*-n32|*"-n32 "|*-melf32bmipn32|*"-melf32bmipn32 ")
|
|
libsuff=32 shlibsuff=N32 libmagic=N32;;
|
|
*-64|*"-64 "|*-melf64bmip|*"-melf64bmip ")
|
|
libsuff=64 shlibsuff=64 libmagic=64-bit;;
|
|
*) libsuff= shlibsuff= libmagic=never-match;;
|
|
esac
|
|
;;
|
|
esac
|
|
shlibpath_var=LD_LIBRARY${shlibsuff}_PATH
|
|
shlibpath_overrides_runpath=no
|
|
sys_lib_search_path_spec="/usr/lib${libsuff} /lib${libsuff} /usr/local/lib${libsuff}"
|
|
sys_lib_dlsearch_path_spec="/usr/lib${libsuff} /lib${libsuff}"
|
|
hardcode_into_libs=yes
|
|
;;
|
|
|
|
# No shared lib support for Linux oldld, aout, or coff.
|
|
linux*oldld* | linux*aout* | linux*coff*)
|
|
dynamic_linker=no
|
|
;;
|
|
|
|
# This must be Linux ELF.
|
|
linux*|k*bsd*-gnu)
|
|
version_type=linux
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
finish_cmds='PATH="\$PATH:/sbin" ldconfig -n $libdir'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
shlibpath_overrides_runpath=no
|
|
# This implies no fast_install, which is unacceptable.
|
|
# Some rework will be needed to allow for fast_install
|
|
# before this can be enabled.
|
|
hardcode_into_libs=yes
|
|
|
|
# We used to test for /lib/ld.so.1 and disable shared libraries on
|
|
# powerpc, because MkLinux only supported shared libraries with the
|
|
# GNU dynamic linker. Since this was broken with cross compilers,
|
|
# most powerpc-linux boxes support dynamic linking these days and
|
|
# people can always --disable-shared, the test was removed, and we
|
|
# assume the GNU/Linux dynamic linker is in use.
|
|
dynamic_linker='GNU/Linux ld.so'
|
|
;;
|
|
|
|
netbsd*)
|
|
version_type=sunos
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
if echo __ELF__ | $CC -E - | grep __ELF__ >/dev/null; then
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
|
|
finish_cmds='PATH="\$PATH:/sbin" ldconfig -m $libdir'
|
|
dynamic_linker='NetBSD (a.out) ld.so'
|
|
else
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${release}${shared_ext} ${libname}${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
dynamic_linker='NetBSD ld.elf_so'
|
|
fi
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
shlibpath_overrides_runpath=yes
|
|
hardcode_into_libs=yes
|
|
;;
|
|
|
|
newsos6)
|
|
version_type=linux
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
shlibpath_overrides_runpath=yes
|
|
;;
|
|
|
|
nto-qnx)
|
|
version_type=linux
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
shlibpath_overrides_runpath=yes
|
|
;;
|
|
|
|
openbsd*)
|
|
version_type=sunos
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
|
|
finish_cmds='PATH="\$PATH:/sbin" ldconfig -m $libdir'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
if test -z "`echo __ELF__ | $CC -E - | grep __ELF__`" || test "$host_os-$host_cpu" = "openbsd2.8-powerpc"; then
|
|
case $host_os in
|
|
openbsd2.[[89]] | openbsd2.[[89]].*)
|
|
shlibpath_overrides_runpath=no
|
|
;;
|
|
*)
|
|
shlibpath_overrides_runpath=yes
|
|
;;
|
|
esac
|
|
else
|
|
shlibpath_overrides_runpath=yes
|
|
fi
|
|
;;
|
|
|
|
os2*)
|
|
libname_spec='$name'
|
|
shrext=".dll"
|
|
need_lib_prefix=no
|
|
library_names_spec='$libname${shared_ext} $libname.a'
|
|
dynamic_linker='OS/2 ld.exe'
|
|
shlibpath_var=LIBPATH
|
|
;;
|
|
|
|
osf3* | osf4* | osf5*)
|
|
version_type=osf
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
sys_lib_search_path_spec="/usr/shlib /usr/ccs/lib /usr/lib/cmplrs/cc /usr/lib /usr/local/lib /var/shlib"
|
|
sys_lib_dlsearch_path_spec="$sys_lib_search_path_spec"
|
|
;;
|
|
|
|
sco3.2v5*)
|
|
version_type=osf
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
;;
|
|
|
|
solaris*)
|
|
version_type=linux
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
shlibpath_overrides_runpath=yes
|
|
hardcode_into_libs=yes
|
|
# ldd complains unless libraries are executable
|
|
postinstall_cmds='chmod +x $lib'
|
|
;;
|
|
|
|
sunos4*)
|
|
version_type=sunos
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
|
|
finish_cmds='PATH="\$PATH:/usr/etc" ldconfig $libdir'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
shlibpath_overrides_runpath=yes
|
|
if test "$with_gnu_ld" = yes; then
|
|
need_lib_prefix=no
|
|
fi
|
|
need_version=yes
|
|
;;
|
|
|
|
sysv4 | sysv4.2uw2* | sysv4.3* | sysv5*)
|
|
version_type=linux
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
case $host_vendor in
|
|
sni)
|
|
shlibpath_overrides_runpath=no
|
|
need_lib_prefix=no
|
|
export_dynamic_flag_spec='${wl}-Blargedynsym'
|
|
runpath_var=LD_RUN_PATH
|
|
;;
|
|
siemens)
|
|
need_lib_prefix=no
|
|
;;
|
|
motorola)
|
|
need_lib_prefix=no
|
|
need_version=no
|
|
shlibpath_overrides_runpath=no
|
|
sys_lib_search_path_spec='/lib /usr/lib /usr/ccs/lib'
|
|
;;
|
|
esac
|
|
;;
|
|
|
|
sysv4*MP*)
|
|
if test -d /usr/nec ;then
|
|
version_type=linux
|
|
library_names_spec='$libname${shared_ext}.$versuffix $libname${shared_ext}.$major $libname${shared_ext}'
|
|
soname_spec='$libname${shared_ext}.$major'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
fi
|
|
;;
|
|
|
|
uts4*)
|
|
version_type=linux
|
|
library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
|
|
soname_spec='${libname}${release}${shared_ext}$major'
|
|
shlibpath_var=LD_LIBRARY_PATH
|
|
;;
|
|
|
|
*)
|
|
dynamic_linker=no
|
|
;;
|
|
esac
|
|
AC_MSG_RESULT([$dynamic_linker])
|
|
test "$dynamic_linker" = no && can_build_shared=no
|
|
])# AC_LIBTOOL_SYS_DYNAMIC_LINKER
|
|
|
|
# AC_LTDL_SHLIBPATH
|
|
# -----------------
|
|
AC_DEFUN([AC_LTDL_SHLIBPATH],
|
|
[AC_REQUIRE([AC_LIBTOOL_SYS_DYNAMIC_LINKER])
|
|
AC_CACHE_CHECK([which variable specifies run-time library path],
|
|
[libltdl_cv_shlibpath_var], [libltdl_cv_shlibpath_var="$shlibpath_var"])
|
|
if test -n "$libltdl_cv_shlibpath_var"; then
|
|
AC_DEFINE_UNQUOTED(LTDL_SHLIBPATH_VAR, "$libltdl_cv_shlibpath_var",
|
|
[Define to the name of the environment variable that determines the dynamic library search path.])
|
|
fi
|
|
])# AC_LTDL_SHLIBPATH
|