6973bf5482
* libF77/configure.in: Define IEEE_COMPLEX_DIVIDE. * libF77/[cz]_div.c: Arrange for compilation under -DIEEE_COMPLEX_DIVIDE to make these routines avoid calling sig_die when the denominator vanishes. * libF77/s_rnge.c: Add casts for the case of sizeof(ftnint) == sizeof(int) < sizeof(long). * libI77/endfile.c: Set state to writing (b->uwrt = 1) when an endfile statement requires copying the file Also, supply a missing (long) cast in the sprintf call. * libI77/sfe.c: Add #ifdef ALWAYS_FLUSH logic, for formatted I/O. From-SVN: r32496
110 lines
3.3 KiB
Plaintext
110 lines
3.3 KiB
Plaintext
# Process this file with autoconf to produce a configure script.
|
|
# Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
|
|
# Contributed by Dave Love (d.love@dl.ac.uk).
|
|
#
|
|
#This file is part of GNU Fortran.
|
|
#
|
|
#GNU Fortran is free software; you can redistribute it and/or modify
|
|
#it under the terms of the GNU General Public License as published by
|
|
#the Free Software Foundation; either version 2, or (at your option)
|
|
#any later version.
|
|
#
|
|
#GNU Fortran is distributed in the hope that it will be useful,
|
|
#but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
#MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
#GNU General Public License for more details.
|
|
#
|
|
#You should have received a copy of the GNU General Public License
|
|
#along with GNU Fortran; see the file COPYING. If not, write to
|
|
#the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
|
|
#02111-1307, USA.
|
|
|
|
AC_PREREQ(2.12.1)
|
|
AC_INIT(getarg_.c)
|
|
|
|
dnl Checks for programs.
|
|
# For g77 we'll set CC to point at the built gcc, but this will get it into
|
|
# the makefiles
|
|
AC_PROG_CC
|
|
|
|
test "$AR" || AR=ar
|
|
AC_SUBST(AR)
|
|
AC_PROG_MAKE_SET
|
|
|
|
dnl Checks for libraries.
|
|
|
|
dnl Checks for header files.
|
|
# Sanity check for the cross-compilation case:
|
|
AC_CHECK_HEADER(stdio.h,:,
|
|
[AC_MSG_ERROR([Can't find stdio.h.
|
|
You must have a usable C system for the target already installed, at least
|
|
including headers and, preferably, the library, before you can configure
|
|
the G77 runtime system. If necessary, install gcc now with \`LANGUAGES=c',
|
|
then the target library, then build with \`LANGUAGES=f77'.])])
|
|
|
|
AC_HEADER_STDC
|
|
dnl We could do this if we didn't know we were using gcc
|
|
dnl AC_MSG_CHECKING(for prototype-savvy compiler)
|
|
dnl AC_CACHE_VAL(g77_cv_sys_proto,
|
|
dnl [AC_TRY_LINK(,
|
|
dnl dnl looks screwy because TRY_LINK expects a function body
|
|
dnl [return 0;} int foo (int * bar) {],
|
|
dnl g77_cv_sys_proto=yes,
|
|
dnl [g77_cv_sys_proto=no
|
|
dnl AC_DEFINE(KR_headers)])])
|
|
dnl AC_MSG_RESULT($g77_cv_sys_proto)
|
|
|
|
AC_MSG_CHECKING(for posix)
|
|
AC_CACHE_VAL(g77_cv_header_posix,
|
|
AC_EGREP_CPP(yes,
|
|
[#include <sys/types.h>
|
|
#include <unistd.h>
|
|
#ifdef _POSIX_VERSION
|
|
yes
|
|
#endif
|
|
],
|
|
g77_cv_header_posix=yes,
|
|
g77_cv_header_posix=no))
|
|
AC_MSG_RESULT($g77_cv_header_posix)
|
|
|
|
# We can rely on the GNU library being posix-ish. I guess checking the
|
|
# header isn't actually like checking the functions, though...
|
|
AC_MSG_CHECKING(for GNU library)
|
|
AC_CACHE_VAL(g77_cv_lib_gnu,
|
|
AC_EGREP_CPP(yes,
|
|
[#include <stdio.h>
|
|
#ifdef __GNU_LIBRARY__
|
|
yes
|
|
#endif
|
|
],
|
|
g77_cv_lib_gnu=yes, g77_cv_lib_gnu=no))
|
|
AC_MSG_RESULT($g77_cv_lib_gnu)
|
|
|
|
dnl Checks for library functions.
|
|
AC_TYPE_SIGNAL
|
|
# we'll get atexit by default
|
|
if test $ac_cv_header_stdc != yes; then
|
|
AC_CHECK_FUNC(atexit,
|
|
AC_DEFINE(onexit,atexit),dnl just in case
|
|
[AC_DEFINE(NO_ONEXIT)
|
|
AC_CHECK_FUNC(onexit,,
|
|
[AC_CHECK_FUNC(on_exit,
|
|
AC_DEFINE(onexit,on_exit),)])])
|
|
else true
|
|
fi
|
|
|
|
dnl perhaps should check also for remainder
|
|
dnl Unfortunately, the message implies we're just checking for -lm...
|
|
AC_CHECK_LIB(m,drem,AC_DEFINE(IEEE_drem))
|
|
|
|
AC_DEFINE(Skip_f2c_Undefs)
|
|
AC_DEFINE(IEEE_COMPLEX_DIVIDE)
|
|
|
|
AC_OUTPUT(Makefile)
|
|
|
|
dnl Local Variables:
|
|
dnl comment-start: "dnl "
|
|
dnl comment-end: ""
|
|
dnl comment-start-skip: "\\bdnl\\b\\s *"
|
|
dnl End:
|