d4e0a1c056
2009-09-07 H.J. Lu <hongjiu.lu@intel.com>
Ralf Wildenhues <Ralf.Wildenhues@gmx.de>
PR libstdc++/41280
* configure.ac: Run "${multi_basedir}/config-ml.in" to generate
MULTISUBDIR = in subdirectory Makefiles, with ml_norecursion set.
* configure: Regenerate.
Co-Authored-By: Ralf Wildenhues <Ralf.Wildenhues@gmx.de>
From-SVN: r151476
420 lines
13 KiB
Plaintext
420 lines
13 KiB
Plaintext
# Process this file with autoreconf to produce a configure script.
|
|
|
|
AC_PREREQ(2.64)
|
|
AC_INIT(package-unused, version-unused,, libstdc++)
|
|
AC_CONFIG_SRCDIR(src/ios.cc)
|
|
AC_CONFIG_HEADER(config.h)
|
|
|
|
# This works around the fact that libtool configuration may change LD
|
|
# for this particular configuration, but some shells, instead of
|
|
# keeping the changes in LD private, export them just because LD is
|
|
# exported. Only used at the end of this file.
|
|
### am handles this now? ORIGINAL_LD_FOR_MULTILIBS=$LD
|
|
|
|
# For libtool versioning info, format is CURRENT:REVISION:AGE
|
|
libtool_VERSION=6:14:0
|
|
AC_SUBST(libtool_VERSION)
|
|
|
|
# Find the rest of the source tree framework.
|
|
AM_ENABLE_MULTILIB(, ..)
|
|
|
|
# Gets build, host, target, *_vendor, *_cpu, *_os, etc.
|
|
#
|
|
# You will slowly go insane if you do not grok the following fact: when
|
|
# building v3 as part of the compiler, the top-level /target/ becomes the
|
|
# library's /host/. configure then causes --target to default to --host,
|
|
# exactly like any other package using autoconf. Therefore, 'target' and
|
|
# 'host' will always be the same. This makes sense both for native and
|
|
# cross compilers, just think about it for a little while. :-)
|
|
#
|
|
# Also, if v3 is being configured as part of a cross compiler, the top-level
|
|
# configure script will pass the "real" host as $with_cross_host.
|
|
#
|
|
# Do not delete or change the following two lines. For why, see
|
|
# http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
|
|
AC_CANONICAL_SYSTEM
|
|
target_alias=${target_alias-$host_alias}
|
|
|
|
# Handy for debugging:
|
|
#AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
|
|
|
|
if test "$build" != "$host"; then
|
|
# We are being configured with some form of cross compiler.
|
|
GLIBCXX_IS_NATIVE=false
|
|
case "$host","$target" in
|
|
# Darwin crosses can use the host system's libraries and headers,
|
|
# because of the fat library support. Of course, it must be the
|
|
# same version of Darwin on both sides. Allow the user to
|
|
# just say --target=foo-darwin without a version number to mean
|
|
# "the version on this system".
|
|
*-*-darwin*,*-*-darwin*)
|
|
hostos=`echo $host | sed 's/.*-darwin/darwin/'`
|
|
targetos=`echo $target | sed 's/.*-darwin/darwin/'`
|
|
if test $hostos = $targetos -o $targetos = darwin ; then
|
|
GLIBCXX_IS_NATIVE=true
|
|
fi
|
|
;;
|
|
|
|
*)
|
|
GCC_NO_EXECUTABLES
|
|
;;
|
|
esac
|
|
else
|
|
GLIBCXX_IS_NATIVE=true
|
|
fi
|
|
|
|
# Sets up automake. Must come after AC_CANONICAL_SYSTEM. Each of the
|
|
# following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
|
|
# 1.x: minimum required version
|
|
# no-define: PACKAGE and VERSION will not be #define'd in config.h (a bunch
|
|
# of other PACKAGE_* variables will, however, and there's nothing
|
|
# we can do about that; they come from AC_INIT).
|
|
# foreign: we don't follow the normal rules for GNU packages (no COPYING
|
|
# file in the top srcdir, etc, etc), so stop complaining.
|
|
# no-dependencies: turns off auto dependency generation (just for now)
|
|
# -Wall: turns on all automake warnings...
|
|
# -Wno-portability: ...except this one, since GNU make is now required.
|
|
AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
|
|
AH_TEMPLATE(PACKAGE, [Name of package])
|
|
AH_TEMPLATE(VERSION, [Version number of package])
|
|
|
|
# We're almost certainly being configured before anything else which uses
|
|
# C++, so all of our AC_PROG_* discoveries will be cached. It's vital that
|
|
# we not cache the value of CXX that we "discover" here, because it's set
|
|
# to something unique for us and libjava. Other target libraries need to
|
|
# find CXX for themselves. We yank the rug out from under the normal AC_*
|
|
# process by sneakily renaming the cache variable. This also lets us debug
|
|
# the value of "our" CXX in postmortems.
|
|
#
|
|
# We must also force CXX to /not/ be a precious variable, otherwise the
|
|
# wrong (non-multilib-adjusted) value will be used in multilibs. This
|
|
# little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS. And as a side
|
|
# effect, CXXFLAGS is no longer automagically subst'd, so we have to do
|
|
# that ourselves. Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
|
|
#
|
|
# -fno-builtin must be present here so that a non-conflicting form of
|
|
# std::exit can be guessed by AC_PROG_CXX, and used in later tests.
|
|
|
|
m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
|
|
m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
|
|
m4_define([_AC_ARG_VAR_PRECIOUS],[])
|
|
save_CXXFLAGS="$CXXFLAGS"
|
|
CXXFLAGS="$CXXFLAGS -fno-builtin"
|
|
AC_PROG_CC
|
|
AC_PROG_CXX
|
|
CXXFLAGS="$save_CXXFLAGS"
|
|
m4_rename_force([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
|
|
AC_SUBST(CFLAGS)
|
|
AC_SUBST(CXXFLAGS)
|
|
|
|
# Runs configure.host, and assorted other critical bits. Sets
|
|
# up critical shell variables.
|
|
GLIBCXX_CONFIGURE
|
|
|
|
if test "x${with_newlib}" != "xyes"; then
|
|
AC_LIBTOOL_DLOPEN
|
|
fi
|
|
AM_PROG_LIBTOOL
|
|
AC_SUBST(enable_shared)
|
|
AC_SUBST(enable_static)
|
|
|
|
# Possibly disable most of the library.
|
|
## TODO: Consider skipping unncessary tests altogether in this case, rather
|
|
## than just ignoring the results. Faster /and/ more correct, win win.
|
|
GLIBCXX_ENABLE_HOSTED
|
|
|
|
# Enable compiler support that doesn't require linking.
|
|
GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
|
|
GLIBCXX_ENABLE_PCH($is_hosted)
|
|
GLIBCXX_ENABLE_THREADS
|
|
GLIBCXX_ENABLE_ATOMIC_BUILTINS
|
|
|
|
# Checks for compiler support that doesn't require linking.
|
|
GLIBCXX_CHECK_COMPILER_FEATURES
|
|
|
|
# Enable all the variable C++ runtime options that don't require linking.
|
|
GLIBCXX_ENABLE_CSTDIO
|
|
GLIBCXX_ENABLE_CLOCALE
|
|
GLIBCXX_ENABLE_ALLOCATOR
|
|
GLIBCXX_ENABLE_CHEADERS($c_model) dnl c_model from configure.host
|
|
GLIBCXX_ENABLE_LONG_LONG([yes])
|
|
GLIBCXX_ENABLE_WCHAR_T([yes])
|
|
GLIBCXX_ENABLE_C99([yes])
|
|
GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
|
|
GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
|
|
GLIBCXX_ENABLE_DEBUG([no])
|
|
GLIBCXX_ENABLE_PARALLEL([yes])
|
|
GLIBCXX_ENABLE_CXX_FLAGS
|
|
GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
|
|
|
|
# Checks for operating systems support that doesn't require linking.
|
|
GLIBCXX_CHECK_SYSTEM_ERROR
|
|
|
|
# For the streamoff typedef.
|
|
GLIBCXX_CHECK_INT64_T
|
|
|
|
# For LFS support.
|
|
GLIBCXX_CHECK_LFS
|
|
|
|
# For showmanyc_helper().
|
|
AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
|
|
GLIBCXX_CHECK_POLL
|
|
GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
|
|
|
|
# For xsputn_2().
|
|
AC_CHECK_HEADERS(sys/uio.h)
|
|
GLIBCXX_CHECK_WRITEV
|
|
|
|
# For C99 support to TR1.
|
|
GLIBCXX_CHECK_C99_TR1
|
|
|
|
# For common values of EOF, SEEK_CUR, SEEK_END.
|
|
GLIBCXX_CHECK_STDIO_MACROS
|
|
|
|
# For gettimeofday support.
|
|
GLIBCXX_CHECK_GETTIMEOFDAY
|
|
|
|
# For clock_gettime, nanosleep and sched_yield support.
|
|
# NB: The default is [no], because otherwise it requires linking.
|
|
GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
|
|
|
|
# For gthread support
|
|
GLIBCXX_CHECK_GTHREADS
|
|
|
|
AC_LC_MESSAGES
|
|
|
|
# Check for available headers.
|
|
AC_CHECK_HEADERS([endian.h float.h fp.h ieeefp.h inttypes.h locale.h \
|
|
machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
|
|
strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
|
|
sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
|
|
wchar.h wctype.h])
|
|
|
|
# Only do link tests if native. Else, hardcode.
|
|
if $GLIBCXX_IS_NATIVE; then
|
|
|
|
# We can do more elaborate tests that assume a working linker.
|
|
CANADIAN=no
|
|
|
|
GLIBCXX_CHECK_LINKER_FEATURES
|
|
GLIBCXX_CHECK_MATH_SUPPORT
|
|
GLIBCXX_CHECK_STDLIB_SUPPORT
|
|
|
|
# For /dev/random and /dev/urandom for TR1.
|
|
GLIBCXX_CHECK_RANDOM_TR1
|
|
|
|
# For TLS support.
|
|
GCC_CHECK_TLS
|
|
|
|
# For iconv support.
|
|
AM_ICONV
|
|
|
|
else
|
|
|
|
# This lets us hard-code the functionality we know we'll have in the cross
|
|
# target environment. "Let" is a sugar-coated word placed on an especially
|
|
# dull and tedious hack, actually.
|
|
#
|
|
# Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
|
|
# that involve linking, can't be used:
|
|
# "cannot open sim-crt0.o"
|
|
# "cannot open crt0.o"
|
|
# etc. All this is because there currently exists no unified, consistent
|
|
# way for top level CC information to be passed down to target directories:
|
|
# newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
|
|
# When all of that is done, all of this hokey, excessive AC_DEFINE junk for
|
|
# crosses can be removed.
|
|
|
|
# If Canadian cross, then don't pick up tools from the build directory.
|
|
# Used only in GLIBCXX_EXPORT_INCLUDES.
|
|
if test -n "$with_cross_host" &&
|
|
test x"$build_alias" != x"$with_cross_host" &&
|
|
test x"$build" != x"$target";
|
|
then
|
|
CANADIAN=yes
|
|
else
|
|
CANADIAN=no
|
|
fi
|
|
|
|
# Construct crosses by hand, eliminating bits that need ld...
|
|
# GLIBCXX_CHECK_MATH_SUPPORT
|
|
|
|
# First, test for "known" system libraries. We may be using newlib even
|
|
# on a hosted environment.
|
|
if test "x${with_newlib}" = "xyes"; then
|
|
os_include_dir="os/newlib"
|
|
AC_DEFINE(HAVE_HYPOT)
|
|
|
|
# GLIBCXX_CHECK_STDLIB_SUPPORT
|
|
AC_DEFINE(HAVE_STRTOF)
|
|
|
|
AC_DEFINE(HAVE_ACOSF)
|
|
AC_DEFINE(HAVE_ASINF)
|
|
AC_DEFINE(HAVE_ATAN2F)
|
|
AC_DEFINE(HAVE_ATANF)
|
|
AC_DEFINE(HAVE_CEILF)
|
|
AC_DEFINE(HAVE_COSF)
|
|
AC_DEFINE(HAVE_COSHF)
|
|
AC_DEFINE(HAVE_EXPF)
|
|
AC_DEFINE(HAVE_FABSF)
|
|
AC_DEFINE(HAVE_FLOORF)
|
|
AC_DEFINE(HAVE_FMODF)
|
|
AC_DEFINE(HAVE_FREXPF)
|
|
AC_DEFINE(HAVE_LDEXPF)
|
|
AC_DEFINE(HAVE_LOG10F)
|
|
AC_DEFINE(HAVE_LOGF)
|
|
AC_DEFINE(HAVE_MODFF)
|
|
AC_DEFINE(HAVE_POWF)
|
|
AC_DEFINE(HAVE_SINF)
|
|
AC_DEFINE(HAVE_SINHF)
|
|
AC_DEFINE(HAVE_SQRTF)
|
|
AC_DEFINE(HAVE_TANF)
|
|
AC_DEFINE(HAVE_TANHF)
|
|
|
|
AC_DEFINE(HAVE_ICONV)
|
|
else
|
|
GLIBCXX_CROSSCONFIG
|
|
fi
|
|
|
|
# At some point, we should differentiate between architectures
|
|
# like x86, which have long double versions, and alpha/powerpc/etc.,
|
|
# which don't. For the time being, punt.
|
|
if test x"long_double_math_on_this_cpu" = x"yes"; then
|
|
AC_DEFINE(HAVE_ACOSL)
|
|
AC_DEFINE(HAVE_ASINL)
|
|
AC_DEFINE(HAVE_ATAN2L)
|
|
AC_DEFINE(HAVE_ATANL)
|
|
AC_DEFINE(HAVE_CEILL)
|
|
AC_DEFINE(HAVE_COSL)
|
|
AC_DEFINE(HAVE_COSHL)
|
|
AC_DEFINE(HAVE_EXPL)
|
|
AC_DEFINE(HAVE_FABSL)
|
|
AC_DEFINE(HAVE_FLOORL)
|
|
AC_DEFINE(HAVE_FMODL)
|
|
AC_DEFINE(HAVE_FREXPL)
|
|
AC_DEFINE(HAVE_LDEXPL)
|
|
AC_DEFINE(HAVE_LOG10L)
|
|
AC_DEFINE(HAVE_LOGL)
|
|
AC_DEFINE(HAVE_MODFL)
|
|
AC_DEFINE(HAVE_POWL)
|
|
AC_DEFINE(HAVE_SINCOSL)
|
|
AC_DEFINE(HAVE_SINL)
|
|
AC_DEFINE(HAVE_SINHL)
|
|
AC_DEFINE(HAVE_SQRTL)
|
|
AC_DEFINE(HAVE_TANL)
|
|
AC_DEFINE(HAVE_TANHL)
|
|
fi
|
|
fi
|
|
|
|
# Check for _Unwind_GetIPInfo.
|
|
GCC_CHECK_UNWIND_GETIPINFO
|
|
|
|
|
|
GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
|
|
|
|
GCC_HEADER_STDINT(include/gstdint.h)
|
|
|
|
# This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
|
|
GLIBCXX_ENABLE_SYMVERS([yes])
|
|
GLIBCXX_ENABLE_VISIBILITY([yes])
|
|
|
|
ac_ldbl_compat=no
|
|
case "$target" in
|
|
powerpc*-*-linux* | \
|
|
powerpc*-*-gnu* | \
|
|
sparc*-*-linux* | \
|
|
s390*-*-linux* | \
|
|
alpha*-*-linux*)
|
|
AC_TRY_COMPILE(, [
|
|
#if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
|
|
#error no need for long double compatibility
|
|
#endif
|
|
], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
|
|
if test "$ac_ldbl_compat" = yes; then
|
|
AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
|
|
[Define if compatibility should be provided for -mlong-double-64.])
|
|
port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
|
|
fi
|
|
esac
|
|
GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
|
|
|
|
# This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
|
|
GLIBCXX_CONFIGURE_TESTSUITE
|
|
|
|
# Propagate the target-specific source directories through the build chain.
|
|
ATOMICITY_SRCDIR=config/${atomicity_dir}
|
|
ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
|
|
ATOMIC_FLAGS=${atomic_flags}
|
|
CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
|
|
OS_INC_SRCDIR=config/${os_include_dir}
|
|
ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
|
|
ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
|
|
AC_SUBST(ATOMICITY_SRCDIR)
|
|
AC_SUBST(ATOMIC_WORD_SRCDIR)
|
|
AC_SUBST(ATOMIC_FLAGS)
|
|
AC_SUBST(CPU_DEFINES_SRCDIR)
|
|
AC_SUBST(ABI_TWEAKS_SRCDIR)
|
|
AC_SUBST(OS_INC_SRCDIR)
|
|
AC_SUBST(ERROR_CONSTANTS_SRCDIR)
|
|
|
|
|
|
# Determine cross-compile flags and AM_CONDITIONALs.
|
|
#AC_SUBST(GLIBCXX_IS_NATIVE)
|
|
#AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
|
|
GLIBCXX_EVALUATE_CONDITIONALS
|
|
|
|
AC_CACHE_SAVE
|
|
|
|
if test ${multilib} = yes; then
|
|
multilib_arg="--enable-multilib"
|
|
else
|
|
multilib_arg=
|
|
fi
|
|
|
|
# Export all the install information.
|
|
GLIBCXX_EXPORT_INSTALL_INFO
|
|
|
|
# Export all the include and flag information to Makefiles.
|
|
GLIBCXX_EXPORT_INCLUDES
|
|
GLIBCXX_EXPORT_FLAGS
|
|
|
|
if test "$enable_shared" = yes; then
|
|
LIBSUPCXX_PICFLAGS="-prefer-pic"
|
|
else
|
|
LIBSUPCXX_PICFLAGS=
|
|
fi
|
|
AC_SUBST(LIBSUPCXX_PICFLAGS)
|
|
|
|
dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
|
|
dnl which can all be called multiple times as needed, plus one (different)
|
|
dnl AC_OUTPUT macro. This one lists the files to be created:
|
|
AC_CONFIG_FILES(Makefile)
|
|
AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
|
|
|
|
# Multilibs need MULTISUBDIR defined correctly in certain makefiles so
|
|
# that multilib installs will end up installed in the correct place.
|
|
# The testsuite needs it for multilib-aware ABI baseline files.
|
|
# To work around this not being passed down from config-ml.in ->
|
|
# srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
|
|
# append it here. Only modify Makefiles that have just been created.
|
|
#
|
|
# Also, get rid of this simulated-VPATH thing that automake does.
|
|
AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
|
|
[cat > vpsed$$ << \_EOF
|
|
s!`test -f '$<' || echo '$(srcdir)/'`!!
|
|
_EOF
|
|
sed -f vpsed$$ $ac_file > tmp$$
|
|
mv tmp$$ $ac_file
|
|
rm vpsed$$
|
|
echo 'MULTISUBDIR =' >> $ac_file
|
|
ml_norecursion=yes
|
|
. ${multi_basedir}/config-ml.in
|
|
AS_UNSET([ml_norecursion])
|
|
])
|
|
|
|
AC_CONFIG_COMMANDS([generate-headers],
|
|
[(cd include && ${MAKE-make} pch_build= )])
|
|
|
|
dnl And this actually makes things happen:
|
|
AC_OUTPUT
|