b3f8d95d35
* configure.in (arm*-*-eabi*): New target. * configure: Regenerate. * configure.ac (arm*-*-eabi*): New target. (arm*-*-symbianelf*): Likewise. * configure: Regenerated. * config.gcc (arm*-*-eabi*): New target. * defaults.h (TARGET_LIBGCC_FUNCS): New macro. (TARGET_LIB_INT_CMP_BIASED): Likewise. * expmed.c (expand_divmod): Try a two-valued divmod function as a last resort. * gthr.h: Remove bogus tokens at end of #pragma. * optabs.c (expand_twoval_binop_libfunc): New function. (prepare_cmp_insn): Handle the !TARGET_LIB_INT_CMP_BIASED case. (prepare_float_lib_cmp): Try reversing the condition. (debug_optab_libfuncs): New function. * optabs.h (expand_twoval_binop_libfunc): Declare. * config/arm/arm.c (arm_init_libfuncs): New function. (arm_compute_initial_eliminatino_offset): Return HOST_WIDE_INT. (TARGET_INIT_LIBFUNCS): Define it. * config/arm/arm.h (TARGET_BPABI): New macro. * config/arm/arm-protos.h (arm_compute_initial_elimination_offset): Return HOST_WIDE_INT. * config/arm/bpabi.S: New file. * config/arm/bpabi.c: Likewise. * config/arm/bpabi.h: Likewise. * config/arm/ieee754-df.S (__aeabi_dneg): New function or alias. (__aeabi_drsub): Likewise. (__aeabi_dsub): Likewise. (__aeabi_dadd): Likewise. (__aeabi_ui2d): Likewise. (__aeabi_i2d): Likewise. (__aeabi_f2d): Likewise. (__aeabi_dmul): Likewise. (__aeabi_ddiv): Likewise. (__aeabi_cdrcmple): Likewise. (__aeabi_cdcmpeq): Likewise. (__aeabi_cdcmple): Likewise. (__aeabi_dcmpeq): Likewise. (__aeabi_dcmplt): Likewise. (__aeabi_dcmple): Likewise. (__aeabi_dcmpge): Likewise. (__aeabi_dcmpgt): Likewise. (__aeabi_dcmpun): Likewise. (__aeabi_d2iz): Likewise. (__aeabi_d2uiz): Likewise. (__aeabi_d2f): Likewise. * config/arm/ieee754-sf.S (__aeabi_fneg): New function or alias. (__aeabi_frsub): Likewise. (__aeabi_fsub): Likewise. (__aeabi_fadd): Likewise. (__aeabi_ui2f): Likewise. (__aeabi_i2f): Likewise. (__aeabi_fmul): Likewise. (__aeabi_fdiv): Likewise. (__aeabi_cfrcmple): Likewise. (__aeabi_cfcmpeq): Likewise. (__aeabi_cfcmple): Likewise. (__aeabi_fcmpeq): Likewise. (__aeabi_fcmplt): Likewise. (__aeabi_fcmple): Likewise. (__aeabi_fcmpge): Likewise. (__aeabi_fcmpgt): Likewise. (__aeabi_fcmpun): Likewise. (__aeabi_f2iz): Likewise. (__aeabi_f2uiz): Likewise. * config/arm/lib1funcs.asm (ARM_CALL): New macro. (__aeabi_uidivmod): New function or alias. (__aeabi_idivmod): Likewise. (__aeabi_idiv0): Likewise. (__aeabi_ldiv0): Likewise. (__aeabi_llsr): Likewise. (__aeabi_lasr): Likewise. (__aeabi_llsl): Likewise. (bpabi.S): Include it. * config/arm/libgcc-bpabi.ver: New file. * config/arm/symbian.h (ARM_DEFAULT_ABI): Remove. (LINK_SPEC): Remove. * config/arm/t-arm-elf (LIB1ASMFUNCS): Add __aeabi_lcmp and __aeabi_ulcmp. * config/arm/t-bpabi: New file. * doc/tm.texi (TARGET_LIBGCC_FUNCS): New entry. (TARGET_LIB_INT_CMP_BIASED): Likewise. * gcc.dg/testsuite/gcc.dg/arm-eabi1.c: New test. * gcc.dg/dll-2.c: Fix dg-require syntax. * gcc.misc-tests/arm-isr.c (abort): Declare. (exit): Likewise. From-SVN: r85788
100 lines
2.4 KiB
Plaintext
100 lines
2.4 KiB
Plaintext
# -*- Autoconf -*-
|
|
# Process this file with autoconf to produce a configure script.
|
|
|
|
AC_PREREQ(2.59)
|
|
AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
|
|
AC_CONFIG_SRCDIR(ucnid.h)
|
|
AC_CANONICAL_SYSTEM
|
|
AM_INIT_AUTOMAKE(foreign)
|
|
AM_MAINTAINER_MODE
|
|
|
|
# Checks for programs.
|
|
AC_PROG_CC
|
|
AC_PROG_RANLIB
|
|
|
|
# Checks for header files.
|
|
AC_HEADER_TIME
|
|
ACX_HEADER_STRING
|
|
AC_CHECK_HEADERS(iconv.h locale.h fcntl.h limits.h stddef.h \
|
|
stdlib.h strings.h string.h sys/file.h unistd.h)
|
|
|
|
# Checks for typedefs, structures, and compiler characteristics.
|
|
AC_C_CONST
|
|
AC_C_INLINE
|
|
AC_FUNC_OBSTACK
|
|
AC_TYPE_OFF_T
|
|
AC_TYPE_SIZE_T
|
|
AC_STRUCT_TM
|
|
AC_CHECK_SIZEOF(int)
|
|
AC_CHECK_SIZEOF(long)
|
|
AC_CHECK_FUNCS(putc_unlocked fputc_unlocked fputs_unlocked \
|
|
fwrite_unlocked fprintf_unlocked)
|
|
AC_CHECK_DECLS([abort, errno, putc_unlocked, fputc_unlocked,
|
|
fputs_unlocked, fwrite_unlocked, fprintf_unlocked])
|
|
|
|
# Checks for library functions.
|
|
AC_FUNC_ALLOCA
|
|
AC_HEADER_STDC
|
|
AM_LANGINFO_CODESET
|
|
ZW_GNU_GETTEXT_SISTER_DIR
|
|
|
|
AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
|
|
[AC_TRY_COMPILE([
|
|
#include "ansidecl.h"
|
|
#include "system.h"
|
|
],
|
|
[if ((uchar *)0) return 0;
|
|
if (sizeof(uchar)) return 0;],
|
|
ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
|
|
if test $ac_cv_type_uchar = yes; then
|
|
AC_DEFINE(HAVE_UCHAR, 1,
|
|
[Define if <sys/types.h> defines \`uchar'.])
|
|
fi
|
|
|
|
AM_ICONV
|
|
AM_CONDITIONAL(ENABLE_NLS, [test "x$enable_nls" != xno])
|
|
AC_ARG_ENABLE(checking,
|
|
[ --enable-checking enable expensive run-time checks],,
|
|
enable_checking=no)
|
|
|
|
if test $enable_checking != no ; then
|
|
AC_DEFINE(ENABLE_CHECKING, 1,
|
|
[Define if you want more run-time sanity checks.])
|
|
fi
|
|
|
|
m4_changequote(,)
|
|
case $target in
|
|
alpha*-*-* | \
|
|
arm*-*-eabi* | \
|
|
arm*-*-symbianelf* | \
|
|
x86_64-*-* | \
|
|
ia64-*-* | \
|
|
hppa*64*-*-* | parisc*64*-*-* | \
|
|
mips*-*-* | \
|
|
mmix-*-* | \
|
|
powerpc*-*-* | \
|
|
rs6000*-*-* | \
|
|
s390*-*-* | \
|
|
sparc64*-*-* | ultrasparc-*-freebsd* | \
|
|
sparcv9-*-solaris2* | \
|
|
sparc-*-solaris2.[789] | sparc-*-solaris2.1[0-9] | \
|
|
sh[123456789l]*-*-*)
|
|
need_64bit_hwint=yes ;;
|
|
*)
|
|
need_64bit_hwint=no ;;
|
|
esac
|
|
|
|
case $need_64bit_hwint:$ac_cv_sizeof_long in
|
|
*:8 | no:*) host_wide_int=long ;;
|
|
*) host_wide_int='long long' ;;
|
|
esac
|
|
m4_changequote([,])
|
|
|
|
AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
|
|
[Define to the widest efficient host integer type at least
|
|
as wide as the target's size_t type.])
|
|
|
|
AC_CONFIG_HEADERS(config.h:config.in)
|
|
AC_CONFIG_FILES(Makefile)
|
|
AC_OUTPUT
|