55 lines
1.8 KiB
ArmAsm
55 lines
1.8 KiB
ArmAsm
/* Copyright (C) 2001, 2004 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ASM
|
|
#define _SETJMP_H
|
|
#include <bits/setjmp.h>
|
|
#include <asm-syntax.h>
|
|
|
|
/* Jump to the position specified by ENV, causing the
|
|
setjmp call there to return VAL, or 1 if VAL is 0.
|
|
void __longjmp (__jmp_buf env, int val). */
|
|
ENTRY(__longjmp)
|
|
/* Restore registers. */
|
|
/* We add unwind information for the target here. */
|
|
cfi_def_cfa(%rdi, 0)
|
|
cfi_offset(%rbx,JB_RBX*8)
|
|
cfi_offset(%rbp,JB_RBP*8)
|
|
cfi_offset(%r12,JB_R12*8)
|
|
cfi_offset(%r13,JB_R13*8)
|
|
cfi_offset(%r14,JB_R14*8)
|
|
cfi_offset(%r15,JB_R15*8)
|
|
cfi_offset(%rsp,JB_RSP*8)
|
|
cfi_offset(%rip,JB_PC*8)
|
|
movq (JB_RBX*8)(%rdi),%rbx
|
|
movq (JB_RBP*8)(%rdi),%rbp
|
|
movq (JB_R12*8)(%rdi),%r12
|
|
movq (JB_R13*8)(%rdi),%r13
|
|
movq (JB_R14*8)(%rdi),%r14
|
|
movq (JB_R15*8)(%rdi),%r15
|
|
/* Set return value for setjmp. */
|
|
test %esi,%esi
|
|
mov $01,%eax
|
|
cmove %eax,%esi
|
|
mov %esi, %eax
|
|
movq (JB_PC*8)(%rdi),%rdx
|
|
movq (JB_RSP*8)(%rdi),%rsp
|
|
jmpq *%rdx
|
|
END (BP_SYM (__longjmp))
|