b920de1b77
Add architecture support for the MN10300/AM33 CPUs produced by MEI to the kernel. This patch also adds board support for the ASB2303 with the ASB2308 daughter board, and the ASB2305. The only processor supported is the MN103E010, which is an AM33v2 core plus on-chip devices. [akpm@linux-foundation.org: nuke cvs control strings] Signed-off-by: Masakazu Urade <urade.masakazu@jp.panasonic.com> Signed-off-by: Koichi Yasutake <yasutake.koichi@jp.panasonic.com> Signed-off-by: David Howells <dhowells@redhat.com> Signed-off-by: Andrew Morton <akpm@linux-foundation.org> Signed-off-by: Linus Torvalds <torvalds@linux-foundation.org>
91 lines
2.2 KiB
ArmAsm
91 lines
2.2 KiB
ArmAsm
###############################################################################
|
|
#
|
|
# 16550 serial Rx interrupt handler for gdbstub I/O
|
|
#
|
|
# Copyright (C) 2007 Red Hat, Inc. All Rights Reserved.
|
|
# Written by David Howells (dhowells@redhat.com)
|
|
#
|
|
# This program is free software; you can redistribute it and/or
|
|
# modify it under the terms of the GNU General Public Licence
|
|
# as published by the Free Software Foundation; either version
|
|
# 2 of the Licence, or (at your option) any later version.
|
|
#
|
|
###############################################################################
|
|
#include <linux/sys.h>
|
|
#include <linux/linkage.h>
|
|
#include <asm/smp.h>
|
|
#include <asm/cpu-regs.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/frame.inc>
|
|
#include <asm/intctl-regs.h>
|
|
#include <asm/unit/serial.h>
|
|
|
|
.text
|
|
|
|
###############################################################################
|
|
#
|
|
# GDB stub serial receive interrupt entry point
|
|
# - intended to run at interrupt priority 0
|
|
#
|
|
###############################################################################
|
|
.globl gdbstub_io_rx_handler
|
|
.type gdbstub_io_rx_handler,@function
|
|
gdbstub_io_rx_handler:
|
|
movm [d2,d3,a2,a3],(sp)
|
|
|
|
#if 1
|
|
movbu (GDBPORT_SERIAL_IIR),d2
|
|
#endif
|
|
|
|
mov (gdbstub_rx_inp),a3
|
|
gdbstub_io_rx_more:
|
|
mov a3,a2
|
|
add 2,a3
|
|
and 0x00000fff,a3
|
|
mov (gdbstub_rx_outp),d3
|
|
cmp a3,d3
|
|
beq gdbstub_io_rx_overflow
|
|
|
|
movbu (GDBPORT_SERIAL_LSR),d3
|
|
btst UART_LSR_DR,d3
|
|
beq gdbstub_io_rx_done
|
|
movbu (GDBPORT_SERIAL_RX),d2
|
|
movbu d3,(gdbstub_rx_buffer+1,a2)
|
|
movbu d2,(gdbstub_rx_buffer,a2)
|
|
mov a3,(gdbstub_rx_inp)
|
|
bra gdbstub_io_rx_more
|
|
|
|
gdbstub_io_rx_done:
|
|
mov GxICR_DETECT,d2
|
|
movbu d2,(XIRQxICR(GDBPORT_SERIAL_IRQ)) # ACK the interrupt
|
|
movhu (XIRQxICR(GDBPORT_SERIAL_IRQ)),d2 # flush
|
|
movm (sp),[d2,d3,a2,a3]
|
|
bset 0x01,(gdbstub_busy)
|
|
beq gdbstub_io_rx_enter
|
|
rti
|
|
|
|
gdbstub_io_rx_overflow:
|
|
bset 0x01,(gdbstub_rx_overflow)
|
|
bra gdbstub_io_rx_done
|
|
|
|
gdbstub_io_rx_enter:
|
|
or EPSW_IE|EPSW_IM_1,epsw
|
|
add -4,sp
|
|
SAVE_ALL
|
|
|
|
mov 0xffffffff,d0
|
|
mov d0,(REG_ORIG_D0,fp)
|
|
mov 0x280,d1
|
|
|
|
mov fp,d0
|
|
call gdbstub_rx_irq[],0 # gdbstub_rx_irq(regs,excep)
|
|
|
|
and ~EPSW_IE,epsw
|
|
bclr 0x01,(gdbstub_busy)
|
|
|
|
.globl gdbstub_return
|
|
gdbstub_return:
|
|
RESTORE_ALL
|
|
|
|
.size gdbstub_io_rx_handler,.-gdbstub_io_rx_handler
|