OpenE2K/qemu-e2k
13
4
Fork 0
Code Issues 4 Pull Requests Projects 2 Releases Activity

disas: Add disas-objdump.pl

Browse Source 
The script massages the output produced for architectures that are
not supported internally by qemu though an external objdump program
for disassembly.

Signed-off-by: Richard Henderson <rth@twiddle.net>
Signed-off-by: Edgar E. Iglesias <edgar.iglesias@gmail.com>
This commit is contained in:
Richard Henderson 2013-08-16 23:29:46 -07:00 committed by Edgar E. Iglesias
parent c46ffd57a3
commit 8dc6d24091
1 changed files with 87 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

87
scripts/disas-objdump.pl Executable file
View File

@ -0,0 +1,87 @@
#!/usr/bin/perl -w
use File::Temp qw/ tempfile /;
use Getopt::Long;
# Default to the system objdump if a cross-compiler edition not given.
my $aobjdump = "objdump";
my $hobjdump = "";
my $tobjdump = "";
my $hmachine = "";
my $tmachine = "";
GetOptions ('O|objdump=s' => \$aobjdump,
'host-objdump=s' => \$hobjdump,
'target-objdump=s' => \$tobjdump,
'h|host-machine=s' => \$hmachine,
't|target-machine=s' => \$tmachine);
# But we can't default the machines. Sanity check that we've at least one.
die "No host or target machine type" if !$hmachine && !$tmachine;
# Reuse one temp file for all of the hunks.
my ($outh, $outname) = tempfile();
binmode($outh);
END { unlink $outname; }
# Pre-construct the command-lines for executing the dump.
sub mkobjcommand ($$) {
my ($cmd, $mach) = @_;
return 0 if !$mach;
$cmd = $aobjdump if !$cmd;
return "$cmd -m $mach --disassemble-all -b binary $outname";
}
$objdump[1] = mkobjcommand($hobjdump, $hmachine);
$objdump[2] = mkobjcommand($tobjdump, $tmachine);
# Zero-initialize current dumping state.
my $mem = "";
my $inobjd = 0;
sub objcommand {
my $ret = $objdump[$inobjd];
if (!$ret) {
die "Host machine type not specified" if $inobjd == 1;
die "Target machine type not specified" if $inobjd == 2;
die "Internal error";
}
return $ret;
}
while (<>) {
# Collect the data from the relevant OBJD-* lines.
if (/^OBJD-H: /) {
die "Internal error" if $inobjd == 2;
$mem = $mem . pack("H*", substr($_, 8, -1));
$inobjd = 1;
} elsif (/^OBJD-T: /) {
die "Internal error" if $inobjd == 1;
$mem = $mem . pack("H*", substr($_, 8, -1));
$inobjd = 2;
}
# ... which will always be followed by a blank line,
# at which point we should produce our dump.
elsif ($inobjd) {
# Rewrite the temp file in one go; it will usually be small.
sysseek $outh, 0, 0;
truncate $outh, 0;
syswrite $outh, $mem;
# Pipe from objdump...
open IN, "-|", objcommand();
# ... copying all but the first 7 lines of boilerplate to our stdout.
my $i = 0;
while (<IN>) {
print if (++$i > 7);
}
close IN;
print "\n";
$mem = "";
$inobjd = 0;
} else {
print;
}
}