pleroma/lib/pleroma/user.ex

338 lines
9.4 KiB
Elixir
Raw Normal View History

2017-03-20 21:28:31 +01:00
defmodule Pleroma.User do
use Ecto.Schema
import Ecto.{Changeset, Query}
alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
alias Comeonin.Pbkdf2
alias Pleroma.Web.{OStatus, Websub}
2017-05-16 15:31:11 +02:00
alias Pleroma.Web.ActivityPub.Utils
2017-03-20 21:28:31 +01:00
schema "users" do
field :bio, :string
field :email, :string
field :name, :string
field :nickname, :string
field :password_hash, :string
2017-04-15 16:40:09 +02:00
field :password, :string, virtual: true
field :password_confirmation, :string, virtual: true
field :following, {:array, :string}, default: []
2017-03-21 17:53:20 +01:00
field :ap_id, :string
2017-04-16 15:28:28 +02:00
field :avatar, :map
field :local, :boolean, default: true
2017-04-30 15:00:04 +02:00
field :info, :map, default: %{}
field :follower_address, :string
has_many :notifications, Notification
2017-03-20 21:28:31 +01:00
timestamps()
end
2017-03-21 17:53:20 +01:00
2017-04-17 14:12:36 +02:00
def avatar_url(user) do
case user.avatar do
%{"url" => [%{"href" => href} | _]} -> href
_ -> "https://placehold.it/48x48"
end
end
2017-09-16 13:44:08 +02:00
def banner_url(user) do
case user.info["banner"] do
%{"url" => [%{"href" => href} | _]} -> href
_ -> nil
end
end
2017-03-21 17:53:20 +01:00
def ap_id(%User{nickname: nickname}) do
"#{Web.base_url}/users/#{nickname}"
2017-03-21 17:53:20 +01:00
end
def ap_followers(%User{} = user) do
"#{ap_id(user)}/followers"
end
2017-03-22 18:36:08 +01:00
def follow_changeset(struct, params \\ %{}) do
struct
|> cast(params, [:following])
|> validate_required([:following])
end
def info_changeset(struct, params \\ %{}) do
struct
|> cast(params, [:info])
|> validate_required([:info])
end
2017-04-21 00:51:09 +02:00
def user_info(%User{} = user) do
oneself = if user.local, do: 1, else: 0
2017-04-21 00:51:09 +02:00
%{
following_count: length(user.following) - oneself,
note_count: user.info["note_count"] || 0,
follower_count: user.info["follower_count"] || 0
2017-04-21 00:51:09 +02:00
}
end
2017-05-09 18:11:51 +02:00
@email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
def remote_user_creation(params) do
changes = %User{}
|> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
|> validate_required([:name, :ap_id, :nickname])
2017-05-09 18:11:51 +02:00
|> unique_constraint(:nickname)
|> validate_format(:nickname, @email_regex)
|> validate_length(:bio, max: 5000)
2017-05-09 18:11:51 +02:00
|> validate_length(:name, max: 100)
|> put_change(:local, false)
if changes.valid? do
followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
changes
|> put_change(:follower_address, followers)
else
changes
end
2017-05-09 18:11:51 +02:00
end
2017-08-29 15:14:00 +02:00
def update_changeset(struct, params \\ %{}) do
2017-11-19 02:22:07 +01:00
struct
2017-08-29 15:14:00 +02:00
|> cast(params, [:bio, :name])
|> unique_constraint(:nickname)
|> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
|> validate_length(:bio, min: 1, max: 1000)
|> validate_length(:name, min: 1, max: 100)
end
2017-10-19 17:37:24 +02:00
def password_update_changeset(struct, params) do
changeset = struct
|> cast(params, [:password, :password_confirmation])
|> validate_required([:password, :password_confirmation])
|> validate_confirmation(:password)
if changeset.valid? do
hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
changeset
|> put_change(:password_hash, hashed)
else
changeset
end
end
def reset_password(user, data) do
Repo.update(password_update_changeset(user, data))
end
2017-04-15 16:40:09 +02:00
def register_changeset(struct, params \\ %{}) do
changeset = struct
|> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
|> validate_required([:bio, :email, :name, :nickname, :password, :password_confirmation])
|> validate_confirmation(:password)
|> unique_constraint(:email)
|> unique_constraint(:nickname)
2017-04-24 14:33:27 +02:00
|> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
2017-05-09 18:11:51 +02:00
|> validate_format(:email, @email_regex)
2017-08-29 15:14:00 +02:00
|> validate_length(:bio, min: 1, max: 1000)
|> validate_length(:name, min: 1, max: 100)
2017-04-15 16:40:09 +02:00
if changeset.valid? do
hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
2017-04-15 16:40:09 +02:00
ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
changeset
|> put_change(:password_hash, hashed)
|> put_change(:ap_id, ap_id)
|> put_change(:following, [followers])
|> put_change(:follower_address, followers)
2017-04-15 16:40:09 +02:00
else
changeset
end
end
2017-03-22 18:36:08 +01:00
def follow(%User{} = follower, %User{} = followed) do
ap_followers = followed.follower_address
if following?(follower, followed) do
{:error,
"Could not follow user: #{followed.nickname} is already on your list."}
else
2017-05-10 18:43:14 +02:00
if !followed.local && follower.local do
Websub.subscribe(follower, followed)
end
following = [ap_followers | follower.following]
|> Enum.uniq
2017-03-22 18:36:08 +01:00
follower = follower
|> follow_changeset(%{following: following})
|> Repo.update
2017-11-19 02:22:07 +01:00
{:ok, _} = update_follower_count(followed)
follower
end
2017-03-22 18:36:08 +01:00
end
2017-03-23 13:13:09 +01:00
def unfollow(%User{} = follower, %User{} = followed) do
ap_followers = followed.follower_address
if following?(follower, followed) and follower.ap_id != followed.ap_id do
following = follower.following
|> List.delete(ap_followers)
2017-03-23 13:13:09 +01:00
2017-04-21 18:54:21 +02:00
{ :ok, follower } = follower
|> follow_changeset(%{following: following})
|> Repo.update
{:ok, followed} = update_follower_count(followed)
{:ok, follower, Utils.fetch_latest_follow(follower, followed)}
else
{:error, "Not subscribed!"}
end
2017-03-23 13:13:09 +01:00
end
def following?(%User{} = follower, %User{} = followed) do
Enum.member?(follower.following, followed.follower_address)
end
2017-05-11 17:59:11 +02:00
def get_by_ap_id(ap_id) do
Repo.get_by(User, ap_id: ap_id)
end
def get_cached_by_ap_id(ap_id) do
key = "ap_id:#{ap_id}"
2017-05-11 17:59:11 +02:00
Cachex.get!(:user_cache, key, fallback: fn(_) -> get_by_ap_id(ap_id) end)
end
def get_cached_by_nickname(nickname) do
key = "nickname:#{nickname}"
2017-05-01 13:14:58 +02:00
Cachex.get!(:user_cache, key, fallback: fn(_) -> get_or_fetch_by_nickname(nickname) end)
end
2017-04-30 15:06:22 +02:00
def get_by_nickname(nickname) do
Repo.get_by(User, nickname: nickname)
end
def get_cached_user_info(user) do
key = "user_info:#{user.id}"
Cachex.get!(:user_cache, key, fallback: fn(_) -> user_info(user) end)
end
2017-04-30 18:48:48 +02:00
def get_or_fetch_by_nickname(nickname) do
with %User{} = user <- get_by_nickname(nickname) do
user
else _e ->
2017-11-19 02:22:07 +01:00
with [_nick, _domain] <- String.split(nickname, "@"),
2017-05-01 13:14:58 +02:00
{:ok, user} <- OStatus.make_user(nickname) do
2017-04-30 18:48:48 +02:00
user
else _e -> nil
end
end
end
# TODO: these queries could be more efficient if the type in postgresql wasn't map, but array.
def get_followers(%User{id: id, follower_address: follower_address}) do
q = from u in User,
where: fragment("? @> ?", u.following, ^follower_address ),
where: u.id != ^id
{:ok, Repo.all(q)}
end
def get_friends(%User{id: id, following: following}) do
q = from u in User,
where: u.follower_address in ^following,
where: u.id != ^id
{:ok, Repo.all(q)}
end
def increase_note_count(%User{} = user) do
note_count = (user.info["note_count"] || 0) + 1
new_info = Map.put(user.info, "note_count", note_count)
cs = info_changeset(user, %{info: new_info})
Repo.update(cs)
end
def update_note_count(%User{} = user) do
note_count_query = from a in Object,
where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
select: count(a.id)
note_count = Repo.one(note_count_query)
new_info = Map.put(user.info, "note_count", note_count)
cs = info_changeset(user, %{info: new_info})
Repo.update(cs)
end
def update_follower_count(%User{} = user) do
follower_count_query = from u in User,
where: fragment("? @> ?", u.following, ^user.follower_address),
where: u.id != ^user.id,
select: count(u.id)
follower_count = Repo.one(follower_count_query)
new_info = Map.put(user.info, "follower_count", follower_count)
cs = info_changeset(user, %{info: new_info})
Repo.update(cs)
end
2017-11-19 02:22:07 +01:00
def get_notified_from_activity(%Activity{data: %{"to" => to}}) do
query = from u in User,
where: u.ap_id in ^to,
where: u.local == true
Repo.all(query)
end
2017-10-30 19:23:16 +01:00
2017-11-19 02:22:07 +01:00
def get_recipients_from_activity(%Activity{data: %{"to" => to}}) do
query = from u in User,
where: u.ap_id in ^to,
or_where: fragment("? \\\?| ?", u.following, ^to)
query = from u in query,
where: u.local == true
Repo.all(query)
end
2017-10-30 19:23:16 +01:00
def search(query, resolve) do
if resolve do
User.get_or_fetch_by_nickname(query)
end
q = from u in User,
where: fragment("(to_tsvector('english', ?) || to_tsvector('english', ?)) @@ plainto_tsquery('english', ?)", u.nickname, u.name, ^query),
limit: 20
Repo.all(q)
end
2017-11-02 21:57:37 +01:00
def block(user, %{ap_id: ap_id}) do
blocks = user.info["blocks"] || []
new_blocks = Enum.uniq([ap_id | blocks])
new_info = Map.put(user.info, "blocks", new_blocks)
cs = User.info_changeset(user, %{info: new_info})
Repo.update(cs)
end
def unblock(user, %{ap_id: ap_id}) do
blocks = user.info["blocks"] || []
new_blocks = List.delete(blocks, ap_id)
new_info = Map.put(user.info, "blocks", new_blocks)
cs = User.info_changeset(user, %{info: new_info})
Repo.update(cs)
end
def blocks?(user, %{ap_id: ap_id}) do
blocks = user.info["blocks"] || []
Enum.member?(blocks, ap_id)
end
2017-11-30 14:59:44 +01:00
def local_user_query() do
from u in User,
where: u.local == true
end
2017-03-20 21:28:31 +01:00
end