mirror of https://github.com/zedeus/nitter
50 lines
1.6 KiB
Nim
50 lines
1.6 KiB
Nim
# SPDX-License-Identifier: AGPL-3.0-only
|
|
import tables, macros, strutils
|
|
import karax/[karaxdsl, vdom]
|
|
|
|
import renderutils
|
|
import ../types, ../prefs_impl
|
|
|
|
macro renderPrefs*(): untyped =
|
|
result = nnkCall.newTree(
|
|
ident("buildHtml"), ident("tdiv"), nnkStmtList.newTree())
|
|
|
|
for header, options in prefList:
|
|
result[2].add nnkCall.newTree(
|
|
ident("legend"),
|
|
nnkStmtList.newTree(
|
|
nnkCommand.newTree(ident("text"), newLit(header))))
|
|
|
|
for pref in options:
|
|
let procName = ident("gen" & capitalizeAscii($pref.kind))
|
|
let state = nnkDotExpr.newTree(ident("prefs"), ident(pref.name))
|
|
var stmt = nnkStmtList.newTree(
|
|
nnkCall.newTree(procName, newLit(pref.name), newLit(pref.label), state))
|
|
|
|
case pref.kind
|
|
of checkbox: discard
|
|
of input: stmt[0].add newLit(pref.placeholder)
|
|
of select:
|
|
if pref.name == "theme":
|
|
stmt[0].add ident("themes")
|
|
else:
|
|
stmt[0].add newLit(pref.options)
|
|
|
|
result[2].add stmt
|
|
|
|
proc renderPreferences*(prefs: Prefs; path: string; themes: seq[string]): VNode =
|
|
buildHtml(tdiv(class="overlay-panel")):
|
|
fieldset(class="preferences"):
|
|
form(`method`="post", action="/saveprefs", autocomplete="off"):
|
|
refererField path
|
|
|
|
renderPrefs()
|
|
|
|
h4(class="note"):
|
|
text "Preferences are stored client-side using cookies without any personal information."
|
|
|
|
button(`type`="submit", class="pref-submit"):
|
|
text "Save preferences"
|
|
|
|
buttonReferer "/resetprefs", "Reset preferences", path, class="pref-reset"
|